Code:

if (rq->bRequest == USBRQ_HID_SET_REPORT) //(0x09)
{
    if (rq->wValue.bytes[0] == 2)
    {
        DataRemaining = DATA_FTSIZE;
        return USB_NO_MSG;
    }
    else if (rq->wValue.bytes[0] == 1)  // only if the report ID is 1
    {
        DataRemaining = 0;
        return USB_NO_MSG;          // tell driver to call usbFunctionWrite with data
    }
}

Code:

function OpenHID(vid as integer,pid as integer,byval manufacturerp as byte ptr,byval productp as byte ptr,debug as integer=0) as HANDLE export
  dim as string manufacturer, product
  manufacturer = *manufacturerp
  product = *productp

  Type HIDD_ATTRIBUTES
    size As Dword
    VendorID As Word
    ProductID As Word
    VersionNumber As Word
  End Type
  Type DEVICE_INTERFACE_DETAIL_DATA
    cbSize As Integer
    txt As ZString*250
  End Type
  Dim As guid hidGuid
  dim as HDEVINFO deviceInfoList
  dim as SP_DEVICE_INTERFACE_DATA deviceInfo
  dim as HANDLE handle = cast(any ptr,INVALID_HANDLE_VALUE)
  dim as DWORD size
  dim as integer OpenFlag=0
  dim as HIDD_ATTRIBUTES deviceAttributes
  Dim As WString*128 WS
  Dim As DEVICE_INTERFACE_DETAIL_DATA DetailData
  HidD_GetHidGuid (@hidGuid)
  deviceInfoList = SetupDiGetClassDevs(@hidGuid,0,0,DIGCF_PRESENT or DIGCF_INTERFACEDEVICE)
  If deviceInfoList = INVALID_HANDLE_VALUE Then return cast(any ptr,INVALID_HANDLE_VALUE)
  for i as integer=0 to 100000
    if handle <> INVALID_HANDLE_VALUE then CloseHandle(handle):handle = cast(any ptr,INVALID_HANDLE_VALUE)
    deviceInfo.cbSize = sizeof(SP_DEVICE_INTERFACE_DATA)
    if SetupDiEnumDeviceInterfaces(deviceInfoList, 0, @hidGuid, i, @deviceInfo)=0 then return cast(any ptr,INVALID_HANDLE_VALUE)
    SetupDiGetDeviceInterfaceDetail(deviceInfoList,@deviceInfo,0,0,@size,0) 'samo da dobim size!
    DetailData.cbSize=5
    SetupDiGetDeviceInterfaceDetail(deviceInfoList,@deviceInfo,cast(any ptr,@DetailData),size,@size,0)
    handle = CreateFile(detailData.txt, GENERIC_READ or GENERIC_WRITE, FILE_SHARE_READ or FILE_SHARE_WRITE, NULL, OPEN_EXISTING, openFlag, NULL)
    if handle = INVALID_HANDLE_VALUE then return cast(any ptr,INVALID_HANDLE_VALUE)
    deviceAttributes.Size = sizeof(deviceAttributes)
    HidD_GetAttributes(handle, @deviceAttributes)
    if debug then
      print"VID:"; hex(deviceAttributes.VendorID,4);
      print" PID:"; hex(deviceAttributes.ProductID,4);
      print" Ver:"; hex(deviceAttributes.VersionNumber,4);
      If HidD_GetManufacturerString(handle,StrPtr(WS), 128)<>0 Then Print " Mfg:" ; WS;
      If HidD_GetProductString(handle,StrPtr(WS), 128)<>0 Then  Print " Product:" ; WS;
      print
    end if
    if  vid=deviceAttributes.VendorID then
      if  pid=deviceAttributes.ProductID then
        If HidD_GetManufacturerString(handle,StrPtr(WS), 128)<>0 Then
          if manufacturer=Ws then
            If HidD_GetProductString(handle,StrPtr(WS), 128)<>0 Then
              if Product=Ws then
                exit for 'just my device
              end if
            end if
          end if
        end if
      end if
    end if
  next
  SetupDiDestroyDeviceInfoList(deviceInfoList)
  OpenHID=handle
end function